@echo off
chcp 65001 >nul
setlocal

set ACTION=%1
if "%ACTION%"=="" set ACTION=help

if "%ACTION%"=="help" (
    echo.
    echo [DEPLOY] Справка по командам:
    echo ---------------------------------------------
    echo base-build     — Сборка базового php-образа
    echo build          — Сборка всех контейнеров
    echo up             — Запуск контейнеров
    echo down           — Остановка и удаление контейнеров
    echo restart        — Перезапуск всех контейнеров
    echo logs           — Просмотр логов всех сервисов
    echo php-log        — Логи только php-fpm
    echo cron-log       — Логи только cron-контейнера
    echo worker-log     — Логи фонового воркера
    echo help           — Показать эту справку
    echo ---------------------------------------------
    goto :eof
)

echo [INFO] Старт скрипта deploy.cmd
echo [DEBUG] ACTION=%ACTION%

if "%ACTION%"=="base-build" (
    echo [INFO] Сборка базового образа bambolo/php-base:latest
    docker build -f docker/dockerfile_base -t bambolo/php-base:latest .
) else if "%ACTION%"=="build" (
    echo [INFO] Сборка всех контейнеров...
    docker-compose build
) else if "%ACTION%"=="up" (
    echo [INFO] Запуск контейнеров...
    docker-compose up -d
) else if "%ACTION%"=="down" (
    echo [INFO] Остановка и удаление контейнеров...
    docker-compose down
) else if "%ACTION%"=="restart" (
    echo [INFO] Перезапуск контейнеров...
    docker-compose down
    docker-compose up -d
) else if "%ACTION%"=="logs" (
    docker-compose logs -f
) else if "%ACTION%"=="php-log" (
    docker-compose logs -f php
) else if "%ACTION%"=="cron-log" (
    docker-compose logs -f php-cron
) else if "%ACTION%"=="worker-log" (
    docker-compose logs -f bambolo-worker
) else (
    echo [ERROR] Неизвестная команда: %ACTION%
    echo Для справки используйте: deploy.cmd help
)

echo [DONE]
